前回の記事で、PowerPoint 2013で追加されたGuide、Guidesオブジェクトを使ってガイドを追加するPowerPointマクロを紹介しました。

今回は前回のマクロを発展させた、格子状にガイドを追加するマクロを紹介します。

Option Explicit

Public Sub Sample()
  SetGridGuides 20
End Sub

Public Sub SetGridGuides(ByVal interval As Single)
'格子状にガイド設定
  Dim h As Single, w As Single
  Dim i As Single, j As Single
  
  DelAllGuides '事前にガイド削除
  With Application.ActivePresentation.PageSetup
    h = .SlideHeight
    w = .SlideWidth
  End With
  With Application.ActivePresentation
    For i = 0 To h Step interval
      .Guides.Add ppHorizontalGuide, i
    Next
    For j = 0 To w Step interval
      .Guides.Add ppVerticalGuide, j
    Next
  End With
  Application.DisplayGuides = True
End Sub

Private Sub DelAllGuides()
'表示中のプレゼンテーションのガイドをすべて削除する
  Dim i As Long
  
  With Application.ActivePresentation
    If .Guides.Count > 0 Then
      For i = .Guides.Count To 1 Step -1
        .Guides(i).Delete
      Next
    End If
  End With
End Sub

上記マクロを実行すると、下図のように格子状にガイドが表示されます。

グリッドレイアウトのデザインを組むときなんかに使えそうなマクロです。

・・・が、知っての通り、グリッド機能はPowerPointの標準機能として用意されています。

・グリッド線とガイドを表示および使用する
http://office.microsoft.com/ja-jp/HA010235262.aspx

上記のようなマクロを使う利点としては、

・垂直(水平)方向だけグリッド表示できる。
・グリッド幅を自由に設定できる。
・線の色を自由に設定できる。

といったところでしょうか。
標準機能よりも自由度は高いので、どこかで使える場面はあるかもしれません。