当ブログでも「KB2553154の更新プログラムをアンインストールするVBScript」記事で取り上げていますが、昨年末に“2014年12月のWindows Update以降コマンドボタンが使えなくなった”というトラブルが数多く報告されました。
(下記はMicrosoft Communityのスレッドの一例です。)

• 本日実施した Windows Update 後から Excel 2010 の VBA が動作しなくなった
• http://answers.microsoft.com/thread/5886d5cb-2449-46e9-a396-2e8142784b5e
• KB2553154 と MSForms.Exd 削除で対応できていたが、 「実行時エラー ‘57121’ アプリケーション定義またはオブジェクト定義エラーです」 のエラーが表示するようになった。
• http://answers.microsoft.com/thread/a7e658d7-02a9-451e-b39b-916519fa3a1e
• 2014/12/10の一連のwindows updateによりwordのチェックボックスがクリックできなくなる
• http://answers.microsoft.com/thread/e8d3a1f4-4a6f-4eec-8a70-f9069af9dd24
• KB2553154をインストール後の問題
• http://answers.microsoft.com/thread/9c7b865f-a85c-4eb9-af44-e8a536f8225d
• OfficeのUPDATEでExcel2010のボタンが押せなくなった
• http://answers.microsoft.com/thread/0c5bbfc2-3594-49d1-bc1c-5e1a3d28b414
• EXCEL2010のVBで　実行時エラー　”438″ が発生するようになった
• http://answers.microsoft.com/thread/35372e2d-e937-432b-b443-847b7012b39d
• Microsoft Office 2010 32 ビット版 KB2553154のパッチを入れるとエクセルシートに貼ったTextBoxが入力できなくなる
• http://answers.microsoft.com/thread/77902ccd-1abe-492e-bcf2-f54f83bf6fc5
• WindowsUpdate後からの実行時エラー32809について
• http://answers.microsoft.com/thread/86b9570e-5662-4a92-a968-d551a2122fa1
• excel2010 active-xで作ったコマンドボタンが消える
• http://answers.microsoft.com/thread/6b0d3f15-06b7-4695-a5f0-d68a1414115f
• excel2010でActiveXコントロールのオブジェクトが挿入できない、使用できない
• http://answers.microsoft.com/thread/7298c3e3-2c3e-41e8-bbce-4017faa5bcf5
• 12/11のwindows updateでExcel VBAで作成したソフトにトラブル発生！！！
• http://answers.microsoft.com/thread/57ceb786-234c-4605-8b61-b790058f1298
• 2015/02/03 のWindows Update 後から Excel 2010 の VBA が動作しなくなった
• http://answers.microsoft.com/thread/c7548a1e-d799-4636-ae37-96267e748b36
• Excel 2013 VBA のコマンドボタンが作動しない
• http://answers.microsoft.com/thread/6a7ed705-609d-458f-87bb-de630df82207
• VBAで組んだマクロが突然動かない
• http://answers.microsoft.com/thread/6c12681a-bb48-427d-a214-24b11bcfd5fa
• excel VBA コマンドボタンが作動しなくなる
• http://answers.microsoft.com/thread/b6716b9e-5200-4e3e-9b63-6cc52ea928c7
• チェックボックスにチェックがはいらない
• http://answers.microsoft.com/thread/f61a4b66-aed7-48f9-842f-c6de70bf8fe7
• EXCEL 2013 フォームコントロールがPCによって選択出来ない。
• http://answers.microsoft.com/thread/7210420b-4e27-4f17-aa64-581e0e210b66

ActiveX コントロールのキャッシュ(exdファイル)が原因のようで、対処法としては、「“オブジェクトを挿入できません” エラーが MS14-082 セキュリティ更新プログラムをインストールした後に ActiveX カスタム Office ソリューションで表示される」にあるように、Windows Updateで該当パッチ(Office 2007：KB2596927、Office 2010：KB2553154、Office 2013：KB2726958)を当てた後、MSForms.exdファイルを削除する、という方法になります。

上記ページではFix itもすでに公開されていて、このFix itを実行すれば自動的にexdファイルを削除してくれるようです。

そこで気になったのがこのFix itの中身。
一体どのような処理をしているのだろう？と気になったので、ファイルを展開して調べてみました。

すると、MSIファイルの中に「Binary.DeleteOfficeFile」ファイルがあり、そのファイル(VBScript)が実際にexdファイルの削除を行っているようでした。

・Binary.DeleteOfficeFile(Microsoft Fix it 51029)

Dim objFso               : Set objFso = CreateObject("Scripting.FileSystemObject")
Dim objShell             : Set objShell = CreateObject("WScript.shell")

Dim officeFolders : officeFolders = Array("%appdata%\microsoft\forms\",_
                               "%temp%\vbe\",_
                                "%temp%\excel8.0\",_
                                "%temp%\word8.0\",_
                                "%temp%\PPT11.0\",_
                                "%temp%\MicrosoftVisio12\",_
                                "%temp%\MicrosoftVisio14\",_
                                "%temp%\MicrosoftVisio15\")

Dim fileExtensionName : fileExtensionName = "EXD"

For Each officeFolder In officeFolders
    If(objFSO.FolderExists(objShell.ExpandEnvironmentStrings(officeFolder))) then
        Set objFolder = objFSO.GetFolder(objShell.ExpandEnvironmentStrings(officeFolder))
        Set colFiles = objFolder.Files
        For Each objFile in colFiles
            If(UCase(objFso.GetExtensionName(objFile.Path)) = fileExtensionName) Then
                objFso.DeleteFile(objFolder.path & "\" & objFile.Name)
            end if	
        Next
    end if
Next

・Binary.DeleteOfficeFile(Microsoft Fix it 51031) ※ 要管理者権限

On Error Resume Next

Const HKEY_LOCAL_MACHINE = &H80000002

Dim objFso               : Set objFso = CreateObject("Scripting.FileSystemObject")
Dim objShell             : Set objShell = CreateObject("WScript.shell")

Dim currentFolderPath
Dim tempFolderPath
Dim appDataFolderPath
Dim fileExtensionName : fileExtensionName = "EXD"

Dim strComputer : strComputer = "."
Dim objRegistry

Dim strKeyPath  : strKeyPath = "SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList"
 
Set objRegistry = GetObject("winmgmts:\\" & strComputer & "\root\default:StdRegProv")
objRegistry.EnumKey HKEY_LOCAL_MACHINE, strKeyPath, arrSubkeys
 
For Each objSubkey In arrSubkeys

    strValueName = "ProfileImagePath"
    strSubPath = strKeyPath & "\" & objSubkey

    objRegistry.GetExpandedStringValue HKEY_LOCAL_MACHINE,strSubPath,strValueName,strValue
    
    currentFolderPath = strValue

    ' for debug ************************************************
    'Wscript.Echo currentFolderPath 

	If objFSO.FolderExists(objShell.ExpandEnvironmentStrings(currentFolderPath)) Then
		Set currentFolder = objFso.GetFolder(currentFolderPath)

		If objFSO.FolderExists(objShell.ExpandEnvironmentStrings(currentFolderPath & "\AppData\Local\Temp")) or _
		   objFSO.FolderExists(objShell.ExpandEnvironmentStrings(currentFolderPath & "\AppData\Roaming\Microsoft")) Then

			tempFolderPath = objShell.ExpandEnvironmentStrings(currentFolderPath & "\AppData\Local\Temp")
			appDataFolderPath = objShell.ExpandEnvironmentStrings(currentFolderPath & "\AppData\Roaming\Microsoft")

			Dim officeFolders : officeFolders = Array()
			officeFolders = Array(appDataFolderPath & "\forms\", tempFolderPath)                                

			For Each officeFolder In officeFolders
				If(objFSO.FolderExists(objShell.ExpandEnvironmentStrings(officeFolder))) Then
					Set objFolder = objFSO.GetFolder(objShell.ExpandEnvironmentStrings(officeFolder))
					Set colFiles = objFolder.Files
					For Each objFile in colFiles
						If(UCase(objFso.GetExtensionName(objFile.Path)) = fileExtensionName) Then
							
							' for debug ************************************************
							objFso.DeleteFile(objFolder.path & "\" & objFile.Name)
							'Wscript.Echo objFolder.path & "\" & objFile.Name

						End If	
					Next
					ShowSubfolders objFSO.GetFolder(objShell.ExpandEnvironmentStrings(officeFolder))
				End If			
			Next
		End if
	End if


Next


Sub ShowSubFolders(Folder)
On Error Resume Next
    For Each Subfolder in Folder.SubFolders
        Set objFolder = objFSO.GetFolder(Subfolder.Path)
        Set colFiles = objFolder.Files
        For Each objFile in colFiles
		If(UCase(objFso.GetExtensionName(objFile.Path)) = fileExtensionName) Then

			' for debug ************************************************
			objFso.DeleteFile(objFolder.path & "\" & objFile.Name)
			'Wscript.Echo objFolder.path & "\" & objFile.Name

		End If
        Next
        ShowSubFolders Subfolder
    Next
End Sub

なるほど。
コードを見ると、たしかにexdファイルがありそうなフォルダを順番に見て行って、exdファイルがあればそれを削除する、という処理を行っています。

こういった形で未だにVBScriptは使われているのだなー、とちょっと感慨深くなりました。
VBS、未だ死なず。

ただ、今回の一連のトラブルに関しては、

• 「無効なオブジェクトライブラリーです・・」 のメッセージが出てコマンドボタンのVBAが作動しなくなった。
• http://answers.microsoft.com/thread/a5d829f7-5d1e-4254-bdd4-e97e1921aefa
• Form Controls stop working after December 2014 Updates
• http://blogs.technet.com/b/the_microsoft_excel_support_team_blog/archive/2014/12/11/forms-controls-stop-working-after-december-2014-updates-.aspx

にもあるように、“コマンドボタンの名前が変わってしまう”、といった問題が生じることもあるようです。

2015/02/10 時点では、この問題については「This issue is also being reviewed.」となっているので、対処法はまだ出ていないようですが、何か進展があり次第また追記します。