Office関連

各ページの各行の行頭と行末に文字列を挿入するWordマクロ

Word文書の各ページに10行程度の文章があり、各行の行頭と行末に文字列を挿入するマクロを作りたい、との質問をいただきました。

どのような文章なのかが分からないのですが、文字通り【各ページの各行ごと】ということであれば、伊藤さんのブログでも紹介されている「Lineオブジェクト」を使用して、下記のように書くことができます。

Public Sub Sample01()
'各ページの各行の行頭と行末に文字列を挿入
  Dim tmp As Word.WdViewType
  Dim r As Word.Range
  Dim i As Long, j As Long, k As Long
  
  With ActiveDocument.ActiveWindow
    tmp = .View.Type '表示状態を記憶
    .View.Type = wdPrintView '印刷レイアウトに変更
    
    For i = .ActivePane.Pages.Count To 1 Step -1
      For j = .ActivePane.Pages(i).Rectangles.Count To 1 Step -1
        If .ActivePane.Pages(i).Rectangles(j).RectangleType = wdTextRectangle Then
          For k = .ActivePane.Pages(i).Rectangles(j).Lines.Count To 1 Step -1
            Set r = .ActivePane.Pages(i).Rectangles(j).Lines(k).Range
            Select Case r.Characters(Len(r.Text)).Text
              Case vbCr, vbLf, vbCrLf: r.SetRange r.Start, r.End - 1 '改行飛ばし
            End Select
            r.InsertAfter "【行末】"
            r.InsertBefore "【行頭】"
          Next
        End If
      Next
    Next
    .View.Type = tmp '表示状態を元に戻す
  End With
End Sub

【各段落ごと】で良いのであれば、下記のように「Paragraphオブジェクト」を利用すれば良いかと思います。

Public Sub Sample02()
'各段落のはじめと終わりに文字列を挿入
  Dim r As Word.Range
  Dim i As Long
  
  For i = ActiveDocument.Paragraphs.Count To 1 Step -1
    Set r = ActiveDocument.Paragraphs(i).Range
    Select Case r.Characters(Len(r.Text)).Text
      Case vbCr, vbLf, vbCrLf: r.SetRange r.Start, r.End - 1 '改行飛ばし
    End Select
    r.InsertAfter "【行末】"
    r.InsertBefore "【行頭】"
  Next
End Sub

Word マクロの場合は、こういった処理を様々な書き方でできるため、対象となる文章に応じて、処理の仕方を変更する必要があります。

【スナックワールド】ヘブンズリリィブレイドをLv.8まで強化してみました。前のページ

【スナックワールド】ムラマサカリバーをLv.10まで強化してみました。次のページ

関連記事

  1. Office関連

    UI Automationの参考資料

    VBAからUI Automationを扱う際に参考になりそうな資料への…

  2. アイコン一覧

    Office 365アイコン(imageMso)一覧(K,L)

    Office 365のデスクトップ版Officeアプリケーション(Wo…

  3. Office アドイン

    [Office用アプリ]Seller Dashboardの不満点

    当ブログでも散々取り上げていますが、ストア登録の申請含めて、Offic…

  4. Office関連

    [Office 2013]コントロール日英比較表

    日本語版と英語版のOffice 2013でコントロール(コマンド)名や…

  5. Office関連

    テンプレートから簡単に新規文書を作成できるようにするWordテンプレート

    Wordで自作のテンプレートを利用して文書を作成するとき、2007以降…

  6. Office関連

    Office XP Developer Toolsでリボン対応のCOMアドインを作成する。

    「Visual Basic 6でリボン対応のアドインを作成する」ではV…

コメント

  • コメント (0)

  • トラックバックは利用できません。

  1. この記事へのコメントはありません。

Time limit is exhausted. Please reload CAPTCHA.

※本ページはプロモーションが含まれています。

Translate

最近の記事

アーカイブ

PAGE TOP