文字列操作を行うマクロを書いているとき、テスト用に「あいうえおかきくけこ…」と適当な文字列を入力することがあるのですが、毎回毎回入力するのは大変なので、適当な文字列を挿入するマクロを用意することにしました。

Option Explicit

Public Sub Sample()
  InsertDummyString 2, 3, True, "," '都道府県,3回繰り返し,["]囲み,[,]区切り
End Sub

Public Sub InsertDummyString(Optional ByVal TextType As Integer = 0, _
                             Optional ByVal RepeatCount As Integer = 1, _
                             Optional ByVal OptQuot As Boolean = False, _
                             Optional ByVal OptSep As String = "")
'テスト用文字列挿入
  Dim aryAiueo As Variant
  Dim aryIroha As Variant
  Dim aryTodohuken As Variant
  Dim aryEto As Variant
  Dim aryJikkan As Variant
  Dim aryKensei As Variant
  Dim ary As Variant
  Dim str As String
  Dim i As Long, j As Long
  
  aryAiueo = Array("あ", "い", "う", "え", "お", _
                   "か", "き", "く", "け", "こ", _
                   "さ", "し", "す", "せ", "そ", _
                   "た", "ち", "つ", "て", "と", _
                   "な", "に", "ぬ", "ね", "の", _
                   "は", "ひ", "ふ", "へ", "ほ", _
                   "ま", "み", "む", "め", "も", _
                   "や", "ゆ", "よ", _
                   "ら", "り", "る", "れ", "ろ", _
                   "わ", "ゐ", "ゑ", "を", "ん")
  aryIroha = Array("い", "ろ", "は", "に", "ほ", "へ", "と", _
                   "ち", "り", "ぬ", "る", "を", _
                   "わ", "か", "よ", "た", "れ", "そ", _
                   "つ", "ね", "な", "ら", "む", _
                   "う", "ゐ", "の", "お", "く", "や", "ま", _
                   "け", "ふ", "こ", "え", "て", _
                   "あ", "さ", "き", "ゆ", "め", "み", "し", _
                   "ゑ", "ひ", "も", "せ", "す")
  aryTodohuken = Array("北海道", "青森県", "岩手県", "宮城県", "秋田県", _
                       "山形県", "福島県", "茨城県", "栃木県", "群馬県", _
                       "埼玉県", "千葉県", "東京都", "神奈川県", "新潟県", _
                       "富山県", "石川県", "福井県", "山梨県", "長野県", _
                       "岐阜県", "静岡県", "愛知県", "三重県", "滋賀県", _
                       "京都府", "大阪府", "兵庫県", "奈良県", "和歌山県", _
                       "鳥取県", "島根県", "岡山県", "広島県", "山口県", _
                       "徳島県", "香川県", "愛媛県", "高知県", "福岡県", _
                       "佐賀県", "長崎県", "熊本県", "大分県", "宮崎県", _
                       "鹿児島県", "沖縄県")
  aryEto = Array("子", "丑", "寅", "卯", _
                 "辰", "巳", "午", "未", _
                 "申", "酉", "戌", "亥")
  aryJikkan = Array("甲", "乙", "丙", "丁", "戊", _
                    "己", "庚", "辛", "壬", "癸")
  aryKensei = Array("内閣府", "復興庁", "総務省", "法務省", "外務省", _
                    "財務省", "文部科学省", "厚生労働省", "農林水産省", "経済産業省", _
                    "国土交通省", "環境省", "防衛省")
  ary = Array(aryAiueo, aryIroha, aryTodohuken, _
              aryEto, aryJikkan, aryKensei)
  Select Case TextType
    Case LBound(ary) To UBound(ary)
    Case Else: TextType = 0
  End Select
  Select Case RepeatCount
    Case 1 To 99
    Case Else: RepeatCount = 1
  End Select
  
  str = ""
  For j = 1 To RepeatCount
    For i = LBound(ary(TextType)) To UBound(ary(TextType))
      If OptQuot = True Then
        str = str & ChrW(&H22) & ary(TextType)(i) & ChrW(&H22)
      Else
        str = str & ary(TextType)(i)
      End If
      If i <> UBound(ary(TextType)) Then str = str & OptSep
    Next
    If j <> RepeatCount Then str = str & OptSep
  Next
  Selection.TypeText str
End Sub

五十音順やいろは順の平仮名や都道府県、干支といった文字列を指定した回数分繰り返して挿入することができます。
(オマケとしてダブルクォーテーション囲みや区切り文字も指定できるようにしました。)

Lorem ipsumのようなダミーテキストでも良かったのですが、Wordには元々「rand() 関数」が用意されているので、文章の場合はそちらを使うことにします。