「住所から郵便番号 VBA」といったキーワード検索でのアクセスがあったので、簡単な処理を考えてみました。

住所と郵便番号の変換で、真っ先に思いつくのが「郵便番号変換ウィザード」です。

・住所から郵便番号、または郵便番号から住所を入力する(～ Excel 2003)
http://office.microsoft.com/ja-jp/HP001057416.aspx
・住所から郵便番号、または郵便番号から住所を入力する(Excel 2007 ～)
http://office.microsoft.com/ja-jp/HP010077514.aspx

セル範囲を指定して一括で郵便番号←→住所の変換が出来るのは便利なのですが、マクロから呼び出すのにいちいちウィザードを立ち上げるのは効率がよくありません。

住所から郵便番号の変換さえ行えれば良いので、CodePlexにある郵便番号変換ウィザードのソースコードから必要な部分だけを取り出してみました。

Option Explicit

Private Declare Function AdvZipOpen Lib "MSYUBIN7" () As Integer
Private Declare Function MSYubin7SetKey Lib "MSYUBIN7" (ByVal KEYWORD As Long) As Integer
Private Declare Function SetHyphenMode Lib "MSYUBIN7" (ByVal iHyphenMode As Long) As Integer
Private Declare Function Yubin57 Lib "MSYUBIN7" Alias "yubin57" (ByVal szAddress As String, _
                                                                 ByVal szZip5Code As String, _
                                                                 ByVal szZip7Code As String, _
                                                                 ByVal szBarCode As String) As Integer

Private Const cKEYWORD = 776219008

Public Sub Sample()
  Debug.Print GetZipCode7("沖縄県那覇市首里金城町１－２")
End Sub

Public Function GetZipCode7(ByVal Addr As String) As String
  Dim szZip7 As String * 8
  Dim szRet As String
  Dim iRet As Integer
  Dim i As Long
  
  '初期化
  szRet = ""
  MSYubin7SetKey cKEYWORD ' set the password to use MSYUBIN7.DLL
  AdvZipOpen  'open ZIP dictionary
  SetHyphenMode 1 'ハイフン有
  
  iRet = Yubin57(Addr, vbNullString, szZip7, vbNullString)
  If (iRet And 1) <> 0 Then
    i = InStr(szZip7, Chr(0))
    If i > 0 Then
      szRet = Trim(Left(szZip7, i - 1))
    Else
      szRet = Trim(szZip7)
    End If
  End If
  GetZipCode7 = szRet
End Function

上記の通り、非常に簡単なコードで住所から郵便番号を取得することができます。

気になるのはYubin7のライセンスですが、YU-TANGさんのHPによると、Officeの正規ユーザーであれば利用しても問題無い様子。
(何年も前の情報なので、今はどうか未確認ですが・・・)

まあ、とりあえず、上記コードで住所から郵便番号の変換ができますので、興味がある方は一度お試しください。

ただし、上記コードはMsyubin7.dllの機能を呼び出しているので、郵便番号変換ウィザードのインストールが必須であることと、住所・郵便番号の情報は郵便番号変換ウィザードに依存しているため、最新の情報では無い場合がある点には注意してください。